XPP tools rename: part 2.

Removed obsolete astribank_hook (not needed) and print_modes (moved to
kernel).


git-svn-id: http://svn.asterisk.org/svn/dahdi/tools/trunk@4416 a0bf4364-ded3-4de4-8d8a-66a801d63aff

3 files changed, 336 insertions, 0 deletions

diff --git a/xpp/perl_modules/Dahdi/Xpp/Line.pm b/xpp/perl_modules/Dahdi/Xpp/Line.pm
new file mode 100644
index 0000000..d627ea4
--- /dev/null
+++ b/xpp/perl_modules/Dahdi/Xpp/Line.pm
@@ -0,0 +1,95 @@
+package Dahdi::Xpp::Line;
+#
+# Written by Oron Peled <oron@actcom.co.il>
+# Copyright (C) 2008, Xorcom
+# This program is free software; you can redistribute and/or
+# modify it under the same terms as Perl itself.
+#
+# $Id$
+#
+use strict;
+use Dahdi::Utils;
+
+my $proc_base = "/proc/xpp";
+
+sub new($$$) {
+	my $pack = shift or die "Wasn't called as a class method\n";
+	my $xpd = shift or die;
+	my $index = shift;
+	defined $index or die;
+	my $self = {};
+	bless $self, $pack;
+	$self->{XPD} = $xpd;
+	$self->{INDEX} = $index;
+	return $self;
+}
+
+sub blink($$) {
+	my $self = shift;
+	my $on = shift;
+	my $xpd = $self->xpd;
+	my $result;
+
+	my $file = "$proc_base/" . $xpd->fqn . "/blink";
+	die "$file is missing" unless -f $file;
+	# First query
+	open(F, "$file") or die "Failed to open $file for reading: $!";
+	$result = <F>;
+	chomp $result;
+	close F;
+	if(defined($on)) {		# Now change
+		my $onbitmask = 1 << $self->index;
+		my $offbitmask = $result & ~$onbitmask;
+
+		$result = $offbitmask;
+		$result |= $onbitmask if $on;
+		open(F, ">$file") or die "Failed to open $file for writing: $!";
+		print F "$result";
+		if(!close(F)) {
+			if($! == 17) {	# EEXISTS
+				# good
+			} else {
+				undef $result;
+			}
+		}
+	}
+	return $result;
+}
+
+sub create_all($$) {
+	my $pack = shift or die "Wasn't called as a class method\n";
+	my $xpd = shift || die;
+	my $procdir = shift || die;
+	local $/ = "\n";
+	my @lines;
+	for(my $i = 0; $i < $xpd->{CHANNELS}; $i++) {
+		my $line = Dahdi::Xpp::Line->new($xpd, $i);
+		push(@lines, $line);
+	}
+	$xpd->{LINES} = \@lines;
+	my ($infofile) = glob "$procdir/*_info";
+	die "Failed globbing '$procdir/*_info'" unless defined $infofile;
+	my $type = $xpd->type;
+	open(F, "$infofile") || die "Failed opening '$infofile': $!";
+	my $battery_info = 0;
+	while (<F>) {
+		chomp;
+		if($type eq 'FXO') {
+			$battery_info = 1 if /^Battery:/;
+			if($battery_info && s/^\s*on\s*:\s*//) {
+				my @batt = split;
+				foreach my $l (@lines) {
+					die unless @batt;
+					my $state = shift @batt;
+					$l->{BATTERY} = ($state eq '+') ? 1 : 0;
+				}
+				$battery_info = 0;
+				die if @batt;
+			}
+		}
+	}
+	close F;
+}
+
+
+1;
diff --git a/xpp/perl_modules/Dahdi/Xpp/Xbus.pm b/xpp/perl_modules/Dahdi/Xpp/Xbus.pm
new file mode 100644
index 0000000..4e6b2b3
--- /dev/null
+++ b/xpp/perl_modules/Dahdi/Xpp/Xbus.pm
@@ -0,0 +1,118 @@
+package Dahdi::Xpp::Xbus;
+#
+# Written by Oron Peled <oron@actcom.co.il>
+# Copyright (C) 2007, Xorcom
+# This program is free software; you can redistribute and/or
+# modify it under the same terms as Perl itself.
+#
+# $Id$
+#
+use strict;
+use Dahdi::Utils;
+use Dahdi::Xpp::Xpd;
+
+my $proc_base = "/proc/xpp";
+
+sub xpds($) {
+	my $xbus = shift;
+	return @{$xbus->{XPDS}};
+}
+
+sub by_number($) {
+	my $busnumber = shift;
+	die "Missing xbus number parameter" unless defined $busnumber;
+	my @xbuses = Dahdi::Xpp::xbuses();
+
+	my ($xbus) = grep { $_->num == $busnumber } @xbuses;
+	return $xbus;
+}
+
+sub by_label($) {
+	my $label = shift;
+	die "Missing xbus label parameter" unless defined $label;
+	my @xbuses = Dahdi::Xpp::xbuses();
+
+	my ($xbus) = grep { $_->label eq $label } @xbuses;
+	return $xbus;
+}
+
+sub get_xpd_by_number($$) {
+	my $xbus = shift;
+	my $xpdid = shift;
+	die "Missing XPD id parameter" unless defined $xpdid;
+	my @xpds = $xbus->xpds;
+	my ($wanted) = grep { $_->id eq $xpdid } @xpds;
+	return $wanted;
+}
+
+sub new($$) {
+	my $pack = shift or die "Wasn't called as a class method\n";
+	my $self = {};
+	bless $self, $pack;
+	while(@_) {
+		my ($k, $v) = @_;
+		shift; shift;
+		# Keys in all caps
+		$k = uc($k);
+		# Some values are in all caps as well
+		if($k =~ /^(STATUS)$/) {
+			$v = uc($v);
+		}
+		$self->{$k} = $v;
+	}
+	# backward compat for drivers without labels.
+	if(!defined $self->{LABEL}) {
+		$self->{LABEL} = '[]';
+	}
+	$self->{LABEL} =~ s/^\[(.*)\]$/$1/ or die "$self->{NAME}: Bad label";
+	# Fix badly burned labels.
+	$self->{LABEL} =~ s/[[:^print:]]/_/g;
+	$self->{NAME} or die "Missing xbus name";
+	my $prefix = "$proc_base/" . $self->{NAME};
+	my $usbfile = "$prefix/xpp_usb";
+	if(open(F, "$usbfile")) {
+		my $head = <F>;
+		chomp $head;
+		close F;
+		$head =~ s/^device: +([^, ]+)/$1/i or die;
+		$self->{USB_DEVNAME} = $head;
+	}
+	@{$self->{XPDS}} = ();
+	foreach my $dir (glob "$prefix/XPD-??") {
+		my $xpd = Dahdi::Xpp::Xpd->new($self, $dir);
+		push(@{$self->{XPDS}}, $xpd);
+	}
+	@{$self->{XPDS}} = sort { $a->id <=> $b->id } @{$self->{XPDS}};
+	return $self;
+}
+
+sub pretty_xpds($) {
+		my $xbus = shift;
+		my @xpds = sort { $a->id <=> $b->id } $xbus->xpds();
+		my @xpd_types = map { $_->type } @xpds;
+		my $last_type = '';
+		my $mult = 0;
+		my $xpdstr = '';
+		foreach my $curr (@xpd_types) {
+			if(!$last_type || ($curr eq $last_type)) {
+				$mult++;
+			} else {
+				if($mult == 1) {
+					$xpdstr .= "$last_type ";
+				} elsif($mult) {
+					$xpdstr .= "$last_type*$mult ";
+				}
+				$mult = 1;
+			}
+			$last_type = $curr;
+		}
+		if($mult == 1) {
+			$xpdstr .= "$last_type ";
+		} elsif($mult) {
+			$xpdstr .= "$last_type*$mult ";
+		}
+		$xpdstr =~ s/\s*$//;	# trim trailing space
+		return $xpdstr;
+}
+
+1;
diff --git a/xpp/perl_modules/Dahdi/Xpp/Xpd.pm b/xpp/perl_modules/Dahdi/Xpp/Xpd.pm
new file mode 100644
index 0000000..9e22ed2
--- /dev/null
+++ b/xpp/perl_modules/Dahdi/Xpp/Xpd.pm
@@ -0,0 +1,123 @@
+package Dahdi::Xpp::Xpd;
+#
+# Written by Oron Peled <oron@actcom.co.il>
+# Copyright (C) 2007, Xorcom
+# This program is free software; you can redistribute and/or
+# modify it under the same terms as Perl itself.
+#
+# $Id$
+#
+use strict;
+use Dahdi::Utils;
+use Dahdi::Xpp;
+use Dahdi::Xpp::Line;
+
+my $proc_base = "/proc/xpp";
+
+sub blink($$) {
+	my $self = shift;
+	my $on = shift;
+	my $result;
+
+	my $file = "$proc_base/" . $self->fqn . "/blink";
+	die "$file is missing" unless -f $file;
+	# First query
+	open(F, "$file") or die "Failed to open $file for reading: $!";
+	$result = <F>;
+	chomp $result;
+	close F;
+	if(defined($on) and $on ne $result) {		# Now change
+		open(F, ">$file") or die "Failed to open $file for writing: $!";
+		print F ($on)?"0xFFFF":"0";
+		if(!close(F)) {
+			if($! == 17) {	# EEXISTS
+				# good
+			} else {
+				undef $result;
+			}
+		}
+	}
+	return $result;
+}
+
+sub dahdi_registration($$) {
+	my $self = shift;
+	my $on = shift;
+	my $result;
+
+	my $file = "$proc_base/" . $self->fqn . "/dahdi_registration";
+	die "$file is missing" unless -f $file;
+	# First query
+	open(F, "$file") or die "Failed to open $file for reading: $!";
+	$result = <F>;
+	chomp $result;
+	close F;
+	if(defined($on) and $on ne $result) {		# Now change
+		open(F, ">$file") or die "Failed to open $file for writing: $!";
+		print F ($on)?"1":"0";
+		if(!close(F)) {
+			if($! == 17) {	# EEXISTS
+				# good
+			} else {
+				undef $result;
+			}
+		}
+	}
+	return $result;
+}
+
+sub xpds_by_spanno() {
+	my @xbuses = Dahdi::Xpp::xbuses("SORT_CONNECTOR");
+	my @xpds = map { $_->xpds } @xbuses;
+	@xpds = grep { $_->spanno } @xpds;
+	@xpds = sort { $a->spanno <=> $b->spanno } @xpds;
+	my @spanno = map { $_->spanno } @xpds;
+	my @idx;
+	@idx[@spanno] = @xpds;	# The spanno is the index now
+	return @idx;
+}
+
+sub new($$) {
+	my $pack = shift or die "Wasn't called as a class method\n";
+	my $xbus = shift || die;
+	my $procdir = shift || die;
+	my $self = {};
+	bless $self, $pack;
+	$self->{XBUS} = $xbus;
+	$self->{DIR} = $procdir;
+	local $/ = "\n";
+	open(F, "$procdir/summary") || die "Missing summary file in $procdir";
+	my $head = <F>;
+	chomp $head;	# "XPD-00 (BRI_TE ,card present, span 3)"
+	# The driver does not export the number of channels...
+	# Let's find it indirectly
+	while(<F>) {
+		chomp;
+		if(s/^\s*offhook\s*:\s*//) {
+			my @offhook = split;
+			@offhook || die "No channels in '$procdir/summary'";
+			$self->{CHANNELS} = @offhook;
+			last;
+		}
+	}
+	close F;
+	$head =~ s/^(XPD-(\d\d))\s+// || die;
+	$self->{ID} = $2;
+	$self->{FQN} = $xbus->name . "/" . $1;
+	$head =~ s/^.*\(// || die;
+	$head =~ s/\) */, / || die;
+	$head =~ s/\s*,\s*/,/g || die;
+	my ($type,$present,$span,$rest) = split(/,/, $head);
+	#warn "Garbage in '$procdir/summary': rest='$rest'\n" if $rest;
+	if($span =~ s/span\s+(\d+)//) {	# since changeset:5119
+		$self->{SPANNO} = $1;
+	}
+	$self->{TYPE} = $type;
+	$self->{IS_BRI} = ($type =~ /BRI_(NT|TE)/);
+	$self->{IS_PRI} = ($type =~ /[ETJ]1_(NT|TE)/);
+	$self->{IS_DIGITAL} = ( $self->{IS_BRI} || $self->{IS_PRI} );
+	Dahdi::Xpp::Line->create_all($self, $procdir);
+	return $self;
+}
+
+1;